home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / batchut / xecho11.zip / XECHO.ASM < prev    next >
Assembly Source File  |  1988-06-15  |  6KB  |  165 lines
  1.     PAGE ,132
  2. ; XECHO.ASM  version 1.1  -  by John Wright, 19-March-1988
  3. ;
  4. ; Utility for generating character strings which include control and special
  5. ; characters.  Strings are specified on the command line using "Lotus 1-2-3"
  6. ; like syntax with "\nnn" being translated as the ASCII code for decimal 'nnn'.
  7. ; Strings are sent to the standard output and may be redirected to a file or a
  8. ; device.  Note that unlike the ECHO command in DOS, XECHO does not append a
  9. ; CR,LF pair to the output string.
  10. ;
  11. ; Usage:
  12. ;         XECHO [xxxxx....] [> file or device spec]
  13. ;
  14. ;    where "x" can be either:
  15. ;    - any character which can be entered on a DOS command line (ie. blanks
  16. ;      and any keyboard characters or ALT-key sequences not filtered by DOS 
  17. ;      such as CR (Enter), LF, BS, DEL, ^C, ^P, ">", "<", "|", etc.);  all
  18. ;      characters are sent to standard output as is.
  19. ;       - a sequence of characters beginning with "\":
  20. ;      - "\" followed by 1 to 3 digits is translated as the ASCII code 
  21. ;        represented by interpreting the digits as a decimal value modulo
  22. ;        256; the sequence is terminated by a non-digit, the end of the
  23. ;        command line or a fourth digit.
  24. ;     - "\" followed by a non-digit character is translated as that char.
  25. ;
  26. ; Notes:
  27. ;    - TAB characters in the command line string are not expanded.
  28. ;       - leading blanks and TABs (between "xecho" and the first visible char.
  29. ;      following on the command line are skipped; to send strings beginning
  30. ;      with a blanks or tabs use \20 or \9 for at least for the first one.
  31. ;       - trailing blanks and TABs (between the last visible character of the
  32. ;      command and the CR, ">", "<", or "|") are preserved and sent as is.
  33. ;       - "\1", "\01" and "\001" are equivalent (assuming for the first two
  34. ;      cases that the following character is not a digit) to ^A; 
  35. ;       - "\0001" would be translated as ASCII NUL followed by "1".
  36. ;       - to send the back-slash character, "\", use "\\" in the command line.
  37. ;       - "\" at the end of the command line is ignored.
  38. ;       - the command "xecho >null" creates an empty file "null".
  39. ; 
  40. ; XECHO is particularly useful for sending control strings to on-line devices
  41. ; such as printers or modems.  For instance "xecho \15>prn" selects condensed
  42. ; printing on an Epson compatible printer, "xecho \027@>prn" sends a printer
  43. ; reset, and "xecho \12>prn" sends a form-feed.
  44. ;
  45. ; Revisions:
  46. ;    1.0 -  2-March-88, J.W. - original
  47. ;    1.1 - 19-March-88, J.W. - limited no. digits after '\' to 3 for
  48. ;        compatibility with Lotus-style strings + improved code
  49. ;
  50. ; And lest we forget,
  51. ;    "Lotus" *and* "1-2-3" are trademarks of Lotus Development Corp.
  52. ;     "Epson" is a trademark of Seiko Epson Corp.
  53. ;
  54. ; XECHO is declared in the public domain by its author.
  55. ;
  56. ;
  57. escchar    equ '\'        ; escape char for special processing
  58. ;
  59. blank    equ 20h        ; blank char.
  60. tab    equ 09h        ; tab char.
  61. ;
  62. params  equ 80h        ; address of DOS command line buffer
  63. ;
  64. writefh    equ 40h        ; DOS function code to write to a file handle
  65. dosexit    equ 4ch        ; DOS function code to exit program
  66. ;
  67. stdout    equ 1        ; file handle for standard output
  68. ;
  69. ;
  70. doscall    MACRO function    ;; Call the DOS interrupt 
  71.     mov ah,function    ;; Put function number in AH 
  72.     int 21h
  73.     ENDM
  74. ;
  75. ;
  76.     org    0100h
  77. code    segment    public 'CODE'
  78.     assume    cs:code, ds:code, es:code, ss:code
  79. start    proc    far
  80.     mov si,params    ; SI = address of command line buffer
  81.     lodsb        ; load number of chars in param string.
  82.     mov cl,al    ; save it in CX register.
  83.     xor ch,ch    ; (zero high byte)
  84.     mov di,si    ; DI = SI (now params+1) so that the output string
  85.             ; overwrites the parameter string as it is processed.
  86. ;
  87. ;              loop for leading blanks and tabs
  88. ;
  89. loop1:    jcxz term    ; if no more chars, exit without doing anything
  90.     dec cx        ; else decrement CX
  91.     lodsb        ; and load next char.
  92.     cmp al,blank    ; if a blank, loop.
  93.     jz loop1
  94.     cmp al,tab    ; if a tab, loop.
  95.     jz loop1
  96.     jmp chkesc    ; else process it.
  97. ;
  98. ;              loop for characters to be processed
  99. ;
  100. loop2:    jcxz fin    ; if no more, goto output string
  101.     dec cx        ; else decrement CX
  102.     lodsb        ; and load next char.
  103. chkesc:    cmp al,escchar    ; if the escape char ('\')
  104.     jz escape    ; go to process it
  105. store:    stosb        ; else store as output char.
  106.     jmp loop2    ; continue.
  107. ;
  108. ;              process special escape sequences
  109. ;
  110. escape:    jcxz fin    ; if no more, ignore escape and go to output string
  111.     dec cx        ; else decrement CX
  112.     lodsb        ; and load next char.
  113.     cmp al,'0'    ; if less than "0", treat as regular char
  114.     jl store    ; (go store it).
  115.     cmp al,'9'    ; if greater than "9" treat as regular char
  116.     jg store    ; (go store it).
  117.     xor bx,bx    ; else zero BX to hold converted digit
  118.     mov bp,3    ; and set BP to 3, max no. of digits to convert
  119. ;
  120. ;              loop for digits in escape seq.
  121. ;
  122. loop3:    sub al,'0'    ; convert digit char to byte value in AX.
  123.     xor ah,ah    ; (zero high byte)
  124.     add bx,ax    ; BX = BX+AX
  125.     jcxz endesc    ; if no more char in line, finish escape processing
  126.     dec bp        ; else decrement BP
  127.     jz endesc    ; if zero, stop converting & finish escape processing
  128.     dec cx        ; else decrement CX
  129.     lodsb        ; and load next char.
  130.     cmp al,'0'    ; if less than "0", treat as reqular char and
  131.     jl backup    ; end of escape seq.
  132.     cmp al,'9'    ; if greater than "9", treat as regular char and
  133.     jg backup    ; end of escape seq.
  134.             ; else multiply BX by 10
  135.     mov dx,bx    ; (DX = BX)
  136.     shl dx,1    ; (DX = DX*2)
  137.     shl dx,1    ; (DX = DX*4)
  138.     add bx,dx    ; (BX = BX+DX)
  139.     shl bx,1    ; (BX = BX*2).
  140.     jmp loop3    ; goto add new digit into BX and continue
  141. ;
  142. ;              backup posn in command line buffer
  143. ;
  144. backup: inc cx        ; increment CX
  145.     dec si        ; decrement SI
  146. ;
  147. ;              end of escape seq processing
  148. ;
  149. endesc:    mov al,bl    ; AL = low byte of escape seq number in BX
  150.     jmp store    ; go to store it
  151. ;
  152. ;              output string
  153. ;
  154. fin:    mov dx,params+1    ; DX = address of start of output string.
  155.     mov cx,di    ; CX = DI = address of end of output string + 1.
  156.     sub cx,dx    ; CX = CX-DX = number of chars in output string.
  157.     jcxz term    ; if zero, end without doing anything
  158.     mov bx,stdout    ; else BX = file handle for standard output.
  159.     doscall writefh    ; write to file handle
  160. term:    xor al,al    ; zero al for exit code
  161.     doscall dosexit    ; exit program
  162. start    endp
  163.     code    ends
  164.     end
  165.